Sim Files

[Gondwana]

Below is a crude Windows cmd file that might, if you're lucky, show you where your clockface/app files are stored on the Fitbit OS simulator. This can be useful for checking locally-stored files (see /private/data) and inspecting the app snapshot.

@rem Usage: findsim appname
@rem appname need not be complete, but should be sufficient to be unambiguous.
@rem If appname is ambiguous, multiple matches are possible.
@rem If appname contains one or more spaces, surround it with "".
@rem If you don't specify appname on the command line, you will be prompted for it.
@rem The output identifies the location of the app's manifest file,
@rem but everything in the numeric directory relates to your app.
@echo off
@setlocal
if [%1]==[] goto NO_ARG
set name=%1
goto DO_IT
:NO_ARG
set /p name=App name?
:DO_IT
@C:

call :CHECK_DEVICE Ionic higgs
call :CHECK_DEVICE Versa meson
call :CHECK_DEVICE "Versa Lite" gemini
call :CHECK_DEVICE "Versa 2" mira
call :CHECK_DEVICE "Versa 3" atlas
call :CHECK_DEVICE Sense vulcan

@echo.
@pause
@goto :eof

:CHECK_DEVICE deviceName deviceId
set directory="C:\Users\%username%\AppData\Roaming\Fitbit OS Simulator\%2\app\apps"
@cd %directory% 2> nul
if %errorlevel%==1 goto :eof
@findstr /s /I /M /c:%name% manifest.json > nul
@if %errorlevel%==0 (
  @Echo.
  @Echo %~1:
  @CD
  @findstr /s /I /M /c:%name% manifest.json
)
goto :eof

[SunsetRunner]

That's such a great helper!

(I'm only sorry, I switched to mac... there the files are at
...Library\Application Support\Fitbit OS Simulator\<device-name>\app\apps\<kind of intern id>
then inside each apps folder there are all app related files incl. the manifest.json which includes the apps UUID and name )

at ...private/data I now find my .cbor
Under companion\localstorage I find the related data file

Would be so cool, if any mac-expert could write something similar like your cmd for quick access to the files 🙂